Arduino-Projekte [KSR Wiki]

Diese Seite ist nicht editierbar. Du kannst den Quelltext sehen, jedoch nicht verändern. Kontaktiere den Administrator, wenn du glaubst, dass hier ein Fehler vorliegt.
====== Arduino-Projekte ======

===== - Arduino-Box mit LCD – "Hello World" =====

<color #7092be>**Lernziele:** Arduino-Entwicklungsumgeung (IDE) kennenlernen; Programmiersprache C\+\+ kennenlernen; erstes Arduino-Programm schreiben; Display ansteuern.</color>

Zuerst baust du eine Adruino-Box. Das ist eine verschliessbaer **Plastik-Box**, die neben dem **Arduino UNO** folgende Komponenten enthält:
  * Halterung für Arduino
  * Breadboard
  * Display- und Batteriehlaterung (Batterie mit Kabel optional)
  * LCD (Display) und Display-Kabel
  * USB-Kabel für die Verbindung zwischen Arduino und PC

Die Idee der Box: Du kannst auf dem Breadboard elektronische Bauteile aufbringen und mit dem Arduino verbinden. Diesen Aufbau kannst du jederzeit mitnehmen: USB-Kabel rein, Box verschliessen und in den Rucksack!
  - Baue die Box zusammen. **Überlege zuerst gut**, wie du die Teile auf dem Deckel der Box platzierst, sodass es praktisch zum Arbeiten ist (Verbindung zum Laptop, Display-Verbindung etc.). Klebe dann die Teile mit doppelseitigem Klebenband oder Heissleim fest.
  - Informiere dich über die Arduino-Programmierung in der Programmiersprache C\+\+ hier: [[informatik:arduino_programmieren|Arduino programmieren]]
  - Verbinde das Display und teste es: Dein Display soll "Hello World" zeigen. 

===== - Blinkende und mehrfarbige LEDs =====
<color #7092be>**Lernziele:** LEDs, Tasten und Potentiometer mit **digitalen und analogen Ein- und Ausgängen** verbinden und ansteuern.</color>

==== - Blinkende LED ====
  * Verbinde eine LED und einen Vorwiderstand mit einem digitalen Ein/Ausgang, sodass die LED leuchtet, wenn der Ausgang HIGH (5 V) ist.
  * Programmiere den Arduino so, dass die LED mit 2 Hz blinkt.

//Tipp:// Du benötigst die Funktionen ''pinMode()'', ''digitalWrite()'' und ''delay()''.

<nodisp 1>
++++Lösung mit delay()|
<code c++ Blink.ino>
# define ledPin 2

void setup() {
  pinMode(ledPin, OUTPUT); 
}

void loop() {
  digitalWrite(ledPin, HIGH);
  delay(1000);
  digitalWrite(ledPin, LOW);
  delay(1000);
}
</code>
++++
</nodisp>

<nodisp 1>
++++Lösung mit millis()|
<code c++ BlinkMillis.ino>
# define ledPin 2
bool toggleLED = false;
long time1;
int pauseTime = 1000

void setup() {
  pinMode(ledPin, OUTPUT); 
  time1 = millis();
}

void loop() {
  if(millis()-time1 > pauseTime){
    if(toggleLED == true){
      digitalWrite(ledPin, HIGH);
      toggleLED = false;
    }
    else{
      digitalWrite(ledPin, LOW);
      toggleLED = true;
    }
    time1 = millis();
  }
}
</code>
++++
</nodisp>
==== - Blinkende LED mit stufenlos verstellbarer Frequenz ====
  * Verbinde ein 10-kΩ-Potentiometer mit einem analogen Eingang, sodass ein Signal von 0 bis 5 Volt am Eingang anliegt.
  * Programmiere den Arduino so, dass die Frequenz der blinkenden LED mit dem Potentiomter eingestellt werden kann.

//Tipp:// Du benötigst u. a. die Funktion ''analogRead()''. Informiere dich erst über diese Funktion: [[https://docs.arduino.cc/language-reference/de/|Arduino-Referenz]] 

<nodisp 1>
++++Lösung|
<code c++ BlinkTune.ino>
#define ledPin 2   // LED+ über Widerstand auf an Pin 2, LED- auf GND
#define potiPin A0  // Abriff des Potentiometers --> 0...5 V, auf Pin A0.

int analogValue = 0;

void setup() {
  pinMode(ledPin, OUTPUT);
}

void loop() {
  analogValue = analogRead(potiPin);
  digitalWrite(ledPin, HIGH);
  delay(analogValue);
  digitalWrite(ledPin, LOW);
  delay(analogValue);
}
</code>
++++
</nodisp>

==== - Blinkende LED mit stufenweise verstellbarer Frequenz ====
  * Verbinde zwei Tasten mit zwei digitalen Ein/Ausgängen, sodass der Eingang auf LOW (0V) ist, wenn die ensprechende Taste gedrückt ist.
  * Programmiere den Arduino so, dass die Frequenz der blinkenden LED schrittweise zu- oder abnimmt, wenn die eine oder die andere Taste gedrückt wurde.
    * Minmale Frequenz: 0.495 Hz (Periodendauer 2020 ms)
    * Maximale Frequenz: 50 Hz (Periodendauer 20 ms)
    * Schritt: 200 ms

//Tipps://
  * Verwende für die Tasten den pinMode INPUT_PULLUP. Wenn dir nichg ganz klar ist, weshalb das nötig ist: Lehrperson fragen.
  * Ob eine Taste gedrückt ist oder nicht, fragst du innerhalb der loop()-Schleife mit If-Verzweigungen ab (z.B.: if (digitalRead(freqUpPin) == LOW){...}). Da die loop-Schleife mehrere zehntausend Male pro Sekunde durchlaufen wird, ist es gut möglich, dass auch eine sehr kurze Betätigung der Taste mehrmals erkannt wird und damit wie mehrere Betägtigungen wirkt. Das kannst du verhindern, indem du kurz nach Eintritt in die Verzweigung einige Millisekunden wartest (''delay()''). Alles klar? Falls nicht ganz: Lehrperson fragen!

<nodisp 1>
++++Lösung|
<code c++ BlinkSteps.ino>
#define ledPin 2   // LED+ über Widerstand auf an Pin 13, LED- auf GND
#define downPin 4  // Taste "down" verbindet Pin 4 mit GND
#define upPin 5  // Taste "up" verbindet Pin 4 mit GND
#define debounce 200 // Wartezeit (in ms) zur "Entprellung" der Tasten

bool ledOn = false;     // Umschalt-Flag: schalte ein, wenn false – schalte aus, wenn true
int waitTime = 1020;    // setze Wartezeit auf Initialwert
int waitTime_max = 2020;
int waitTime_min = 20;
int waitTime_step = 200;
long time1;

void setup() {
    Serial.begin(9600);  
    pinMode(ledPin, OUTPUT);
    pinMode(downPin, INPUT_PULLUP);
    pinMode(upPin, INPUT_PULLUP);
    time1 = millis();
}

void loop() {
  if (!digitalRead(downPin)){
    delay(debounce);
    if(waitTime > waitTime_min){
      waitTime -= waitTime_step;
    }
    Serial.println(waitTime);
  }
  if (!digitalRead(upPin)){
    delay(debounce);
    if(waitTime < waitTime_max){
      waitTime += waitTime_step;
    }
    Serial.println(waitTime);
  }
  if(millis()-time1 >= waitTime){
    if(ledOn){
      digitalWrite(ledPin, LOW);
      ledOn = false;
    }
    else{
      digitalWrite(ledPin, HIGH);
      ledOn = true;
    }
    time1 = millis();
  }
}
</code>
++++
</nodisp>

==== - RGB-LED ====
  * Verbinde folgende Bauteile mit dem Arduino:
    * [[https://www.adafruit.com/product/848|RGB-LED 10mm]] oder [[https://www.mouser.ch/datasheet/2/180/HV_5RGBXX_5mm_Full_Color_Series-1489147.pdf|RGB-LED 5mm]]
    * Potentiometer
    * drei Tasten
  * Programmiere den Arduino so, dass du die Farben wie folgt verändern kannst:
    * Rot-Anteil stufenlos erhöhen/verringern
    * Grün-Anteil ganz ein oder ganz ausschalten
    * Blau-Anteil schrittweise erhöhen oder verinngern

Tipp: Um unterschiedliche Helligkeitsstufen zu setzen benötigst du **PWM**-Ausgänge, die du mit ''analogWrite()'' ansteuerst:
  * Welche Pins geeignet sind, siehst du in der [[informatik:arduino_programmieren#einfuehrung|Überischt hier]].
  * Du sollst wissen, was PWM ist und wie es funktioniert: Lese [[https://docs.arduino.cc/learn/microcontrollers/analog-output|diese Beschreibung]] und frage nach, wenn etwas nicht ganz klar ist.

<nodisp 1>
++++Lösung|
<code c++ RGB-LED.ino>
/* RGB-LED mit gemeinsamer Annode --> Anode auf +5V.
Kathoden für red, green, blue über Widerstand auf 
folgende PWM-Pins (für green ginge auch anderer Pin,
da grün bloss ein/ausgeschaltet wird): */
#define ledRedPin 9
#define ledGreenPin 10
#define ledBluePin 11

#define potiPin A0  // Abriff des Potentiometers --> 0...5 V, auf Pin A0.
#define downPin 4  // Taste "down" verbindet Pin 4 mit GND
#define upPin 5  // Taste "up" verbindet Pin 5 mit GND
#define onOffPin 6  // Taste "onOff" verbindet Pin 6 mit GND

#define debounce 200 // Wartezeit (in ms) zur "Entprellung" der Tasten

uint8_t red = 255;  // Werte auf HIGH, sodass LED dunkel
bool green = 1;
uint8_t blue = 255;
uint8_t blueStep = 5;

void setup() {
  pinMode(ledRedPin, OUTPUT);
  pinMode(ledGreenPin, OUTPUT);
  pinMode(ledBluePin, OUTPUT);
  pinMode(potiPin, INPUT);
  pinMode(downPin, INPUT_PULLUP);
  pinMode(upPin, INPUT_PULLUP);
  pinMode(onOffPin, INPUT_PULLUP);
}

void loop() {
  red = analogRead(potiPin);
  if(!digitalRead(onOffPin)){
    delay(debounce);
    green = !green;
  }
  if(!digitalRead(downPin)){
    delay(debounce);
    if(blue > 0){
      blue -= blueStep;
    }
  }
  if(!digitalRead(upPin)){
    delay(debounce);
    if(blue < 255){
      blue += blueStep;
    }
  }
  analogWrite(ledRedPin, red);
  digitalWrite(ledGreenPin, green);
  analogWrite(ledBluePin, blue);
}
</code>
++++
</nodisp>

=== Zusatzaufgaben ===
  - Zeige auf dem Display die aktuellen Farbwerte an.
  - Progammiere ein Leuchtmuster: LED-Farbe wechselt regelmässig. 
  - Programmiere mehrere Leuchtmuster, die dann via Display und Tasten wählbar sind. Verwende evtl [[https://www.adafruit.com/category/168|Neo-Pixel-Bautele]] anstelle von RGB-LEDs.

===== - Chronometer =====
<color #7092be>**Lernziele:** Zeitmessung mit millis(), Strings und Formatierungen verwenden, Arrays verwenden, EEPROM beschreiben und auslesen, Bit-Operatoren verwenden.</color>
==== - Chronometer 1 ====
Programmiere den Arduino so, dass du die Zeit stoppen kannst:
  * Bestimmme zwei Eingänge //Start// und //Stop// an die du Tasten zum Starten und Stoppen anschliesst. Verwende die internen Pull-up-Widerstände.
  * Wenn der Eingang //Start// LOW wird, beginnt die Zeitmessung, wenn //Stop// LOW wird, stoppt sie.
  * Die Zeit misst du mit der Funktion [[https://www.arduino.cc/reference/de/language/functions/time/millis/|millis()]].
  * Das LCD zeigt die aktuelle laufende/gestoppte Zeit im Format MM:SS:HH (M=Minuten, S=Sekunden, H=Hundertstelsekunden).
    * Erstelle hierfür eine Funktion z. B. //showTime//, der du eine Zeit in Millisekunden übergeben kannst und die diese Zeit im gewünschten Format aufs Display schreibt. Nutze die Funktion ''sprintf'' für Formatierungen, siehe Beispiele [[https://gist.github.com/ArduinoBasics/6517378fc2ef9e851773837f301b1d55|hier]] und [[https://forum.arduino.cc/t/convert-int-to-sring-with-leading-zero/629313|hier]].

<nodisp 1>
++++Lösung|
<code c++ CrhonoMeter01.cpp> 
/* Chronometer gemäss Aufgabe 1:
 * Start und Stop-Taste für Zeitmessung. Die gestoppte Zeit 
 * wird laufend und bei Betätigung der Stop-Taste angezeigt. */
 
#include <Wire.h> 
#include <LiquidCrystal_I2C.h>

// create object of class LiquidCrytal_I22 and define parametes:
LiquidCrystal_I2C lcd(0x3F, 2, 1, 0, 4, 5, 6, 7, 3, POSITIVE);

// Konstanten festlegen (für bessere Lesbarkeit des Codes):
#define startPin 5
#define stopPin 4
#define debounce 100 // Wartezeit zur "Entprellung" der Tasten (Millisekunden)

// Folgende Variable speichert den Status der Zeitmessung
bool timeRunning; 

// Folgende Variablen speichern Zeiten in Millisekunden:
unsigned long startTime;
unsigned long currentTime;
unsigned long stoppedTime;

// Folgende Vraiabeln dienen der Anzeige im Format MM:SS:HH:
unsigned int minutes;
unsigned int seconds;
unsigned int hundreds;
char timeString[] = "00:00:00";

void setup() {
 // Eingänge definieren:
 pinMode(startPin, INPUT_PULLUP);
 pinMode(stopPin, INPUT_PULLUP);
 
 // Variablen definieren bzw. auf Initial-Werte setzen:
 timeRunning = 0;
 startTime = 0;
 currentTime = 0;
 stoppedTime = 0; 
 
 // Anzeige vorbereiten: 
 lcd.begin(16,2);               // initialize the lcd 
 lcd.clear(); 
 lcd.setCursor(0, 0);                  
 lcd.print("Zeit:");                
}

void loop() {

  if(timeRunning == 1){
    currentTime  =  millis() - startTime;
    lcd.setCursor(8, 0);
    showTime(currentTime);
  }
  
  if (digitalRead(startPin) == LOW) {
     delay(debounce);
     startTime = millis();
     stoppedTime = 0;
     currentTime = 0;
     timeRunning = 1;
  }
  
  if (digitalRead(stopPin) == LOW) {
     delay(debounce);
     stoppedTime =  millis() - startTime;   
     lcd.setCursor(8, 0);
     showTime(stoppedTime);
     timeRunning = 0;
  }
}

void showTime(unsigned long timeMS){
    // Minuten, Sekunden und Hundertstel berechnen:
    minutes = timeMS/60000;
    seconds = (timeMS-minutes*60000)/1000;
    hundreds = (timeMS-minutes*60000-seconds*1000)/10;
    // Werte im gewünschten Format in Array timeString schreiben:
    sprintf(timeString,"%02d:%02d:%02d", minutes, seconds, hundreds);
    // ...und ans LCD ausgeben:
    lcd.print(timeString);
} 
</code>
++++
</nodisp>
==== - Chronometer 2 ====
Speichere dein Programm Chronometer 1 unter neuem Namen und erweitere es wie folgt:
  * Bestimme einen zusätzlichen Eingang //Reset//.
  * Das Display zeigt nun auf der ersten Zeile die laufende/gestoppte Zeit und auf der zweiten Zeile die kürzeste, je gemessene Zeit seit Betätigung der Taste Reset. //Tipp:// Erstelle evtl. eine Funktion //updateTimes//, die die gestoppte und die kürzeste Zeit an richtiger Stelle aufs LCD schreibt.
  * Wenn der Reset-Eingang LOW wird, werden alle gemessenen oder gespeicherten Zeiten auf 0 gesetzt.

<nodisp 1>
++++Lösung|
<code c++ ChronoMeter02.cpp>
/* Chronometer gemäss Aufgabe 2:
 * Start und Stop-Taste für Zeitmessung. Die gestoppte Zeit 
 * wird jeweils bei Betätigung der Stop-Taste angezeigt.
 * Zusätzlich wird die beste seit Reset gemessene Zeit angezeigt.
 * Reset-Taste setzt alle Zeiten zurück.
 */

#include <SoftwareSerial.h>
#include <Wire.h> 
#include <LiquidCrystal_I2C.h>

// create object of class LiquidCrytal_I22 and define parametes:
LiquidCrystal_I2C lcd(0x3F, 2, 1, 0, 4, 5, 6, 7, 3, POSITIVE);

// Konstanten festlegen (für bessere Lesbarkeit des Codes):
#define startPin 5
#define stopPin 4
#define resetPin 3
#define nextPin 2
#define debounce 100 

// Folgende Variable speichert den Status der Zeitmessung
bool timeRunning; 

// Folgende Variablen speichern die Zeiten in Millisekunden:
unsigned long startTime;
unsigned long currentTime;
unsigned long stoppedTime;
unsigned long bestTime;

// Folgende Vraiablen dienen der Anzeige im Format MM:SS:HH:
unsigned int minutes;
unsigned int seconds;
unsigned int hundreds;
char timeString[] = "00:00:00";

void setup() {
 // Eingänge definieren:
 pinMode(startPin, INPUT_PULLUP);
 pinMode(stopPin, INPUT_PULLUP);
 pinMode(resetPin, INPUT_PULLUP);

 // Für Debugging:
 // pinMode(13, OUTPUT);
 // Serial.begin(9600);
 
 // Variablen definieren bzw. auf Initial-Werte setzen:
 timeRunning = 0;
 startTime = 0;
 currentTime = 0;
 stoppedTime = 0; 
 bestTime = 3599990;  // = 59:59:99 (MM:SS:HH)
 
 // Anzeige vorbereiten: 
 lcd.begin(16,2);               // initialize the lcd 
 lcd.clear(); 
 lcd.setCursor(0, 0);                  
 lcd.print("Jetzt:");
 lcd.setCursor(0, 1);
 lcd.print("Beste:");
 updateTimes();                
}

void loop() {
  
  if(timeRunning == 1){
    currentTime  =  millis() - startTime;
    lcd.setCursor(8, 0);
    showTime(currentTime);
  }
  
  if (digitalRead(startPin) == LOW) {
     delay(debounce);
     startTime = millis();
     stoppedTime = 0;
     currentTime = 0;
     timeRunning = 1; 
  }
  
  if (digitalRead(stopPin) == LOW) {
     delay(debounce);
     stoppedTime =  millis() - startTime;   
     // Falls gestoppte Zeit kleiner als beste Zeit ODER falls beste Zeit = 0 (eben zurückgesetzt):
     if(stoppedTime < bestTime || bestTime == 0){
        bestTime = stoppedTime; 
     }
     updateTimes();
     timeRunning = 0;
  }

  if(digitalRead(resetPin) == LOW) {
    stoppedTime = 0;
    bestTime = 0; 
    updateTimes();
    timeRunning = 0;
  }
}

void updateTimes(){
    lcd.setCursor(8, 0);
    showTime(stoppedTime);
    lcd.setCursor(8, 1);
    showTime(bestTime);
}

void showTime(unsigned long timeMS){
    // Minuten, Sekunden und Hundertstel berechnen:
    minutes = timeMS/60000;
    seconds = (timeMS-minutes*60000)/1000;
    hundreds = (timeMS-minutes*60000-seconds*1000)/10;
    // Werte im gewünschten Format in Array timeString schreiben:
    sprintf(timeString,"%02d:%02d:%02d", minutes, seconds, hundreds);
    // ...und ans LCD ausgeben:
    lcd.print(timeString);
}
</code>
++++
</nodisp>
==== - Chronometer 3 ====
Speichere dein Programm Chronometer 2 unter neuem Name und erweitere es wie folgt:
  * Bestimme einen zusätzlichen Eingang //Next//.
  * Dein Programm soll nun die 5 kürzesten Zeiten speichern. Verwende hierzu ein Array (speichert die 5 besten Zeiten in Millisekunden).
  * Das Display zeigt auf der zweiten Zeile jeweils die Position (1. … 5.) der jeweiligen Zeit, also etwa so {{:talit:electronics:pasted:20230301-110103.png}}
  * Wenn der Next-Eingang LOW wird, wird die nächst höhere Position/Zeit angezeigt. Nach Position 5 wird wieder Position 1 angezeigt.
  * Wenn du die Stromversorgung abschaltest, sollen die fünf Zeiten gespeichert bleiben! (Nutze die Bibliothek EEPROM). Erst wenn der Reset-Eingang LOW wird, werden alle gemessenen oder gespeicherte Zeiten auf 0 gesetzt.
  * Erstelle folgende Funktionen:
    * Eine Funktion //sortTimes//, die die Zeiten sortiert, sodass die kürzeste jeweils an erster Stelle im Array steht.
    * Zwei Funktionen //writeTimesEEP// und //readTimesEEP//, die alle fünf Bestzeiten im EEPROM speichern bzw. daraus auslesen. **Challenge:** Verwende nur die EEPROM-Funktionen //EEPROM.write// und //EEPROM.read//, welche jeweils nur ein Byte schreiben/lesen. Nutze [[https://www.arduino.cc/reference/en/language/structure/bitwise-operators/bitshiftleft/|Bit-Schiebe-]] und [[https://www.arduino.cc/reference/en/language/structure/bitwise-operators/bitwiseand/|Bit-Maskierungs]]-Operatoren, um Variablen von längeren Datentypen in mehrere Bytes aufzuteilen bzw. aus meherern Bytes zusammenzusetzen.
      * Alternative zu //EEPROM.write// und //EEPROM.read//: Betrachte EEPROM als ein Array, dessen Elemente 1 Byte gross sind: mit EEPROM[2] greifst du auf Adresse 2 zu.

<nodisp 1>
++++Lösung|
<code c++ ChronoMeter03.cpp>
/* Chronometer gemäss Aufgabe 3:
 * Start und Stop-Taste für Zeitmessung. Die gestoppte Zeit 
 * wird laufend und bei Betätigung der Stop-Taste angezeigt.
 * Zusätzlich werden die besten fünf gemessenen Zeiten inkl. deren Rang angezeigt.
 * Per Next-Taste kann durch die Zeiten "geblättert" werden.
 * Die Zeiten bleiben bei ausgeschaltetem Arduino erhalten (im EEPROM gespeichert). 
 * Nur wenn die Reset-Taste betätigt wird, werden alle Zeiten zurückgesetzt.
 */
 
#include <EEPROM.h>
#include <SoftwareSerial.h>
#include <Wire.h> 
#include <LiquidCrystal_I2C.h>

// create object of class LiquidCrytal_I22 and define parametes:
LiquidCrystal_I2C lcd(0x3F, 2, 1, 0, 4, 5, 6, 7, 3, POSITIVE);

// Konstanten festlegen (für bessere Lesbarkeit des Codes):
#define startPin 5
#define stopPin 4
#define resetPin 3
#define nextPin 2
#define debounce 150  // Wartezeit zur "Entprellung" der Tasten (Millisekunden)

// Folgende Variable speichert den Status der Zeitmessung
bool timeRunning; 

// Folgende Variablen speichern die Zeiten in Millisekunden:
unsigned long startTime;
unsigned long currentTime;
unsigned long stoppedTime;
unsigned long bestTimes[5];   // Array mit den besten fünf Zeiten
unsigned long tempTime;       // Zwischenspeicher für den Wertetausch bei der Sortierung

// Folgende Variablen dienen der Anzeige im Format MM:SS:HH:
unsigned int minutes;
unsigned int seconds;
unsigned int hundreds;
char timeString[] = "00:00:00";

// Variable für den anzuzeigenden Rang:
uint8_t rank;

// Array für EEPROM-Adressen:
int addresses[5] = {0,3,6,9,12};


void setup() {
  /*Für Debugging:
  pinMode(13, OUTPUT);
  Serial.begin(9600);*/
  
  // Eingänge definieren:
  pinMode(startPin, INPUT_PULLUP);
  pinMode(stopPin, INPUT_PULLUP);
  pinMode(resetPin, INPUT_PULLUP);
  pinMode(nextPin, INPUT_PULLUP);
 
  // Variablen definieren bzw. auf Initial-Werte setzen:
  timeRunning = 0;
  startTime = 0;
  currentTime = 0;
  stoppedTime = 0;
  rank = 0;

  // Beste fünf Zeiten aus EEPROM lesen:
  readTimesEEP();
 
  // Anzeige vorbereiten: 
  lcd.begin(16,2);               // initialize the lcd 
  lcd.clear(); 
  lcd.setCursor(0, 0);                  
  lcd.print("Jetzt:");
  lcd.setCursor(0, 1);
  lcd.print("Rang  :");
  updateTimes();
}


void loop() {
  
  if(timeRunning == 1){
    currentTime  =  millis() - startTime;
    lcd.setCursor(8, 0);
    showTime(currentTime);
  }
  
  if (digitalRead(startPin) == LOW) {
     delay(debounce);
     startTime = millis();
     stoppedTime = 0;
     currentTime = 0;
     timeRunning = 1;  
  }
  
  if (digitalRead(stopPin) == LOW) {
     delay(debounce);
     stoppedTime =  millis() - startTime;   
     // Falls gestoppte Zeit kleiner als fünft-beste Zeit ODER falls diese = 0:
     if(stoppedTime < bestTimes[4] || bestTimes[4] == 0){
        bestTimes[4] = stoppedTime;
        sortTimes();
        storeTimesEEP();
     }
     updateTimes();
     timeRunning = 0;
  }

  if(digitalRead(resetPin) == LOW) {
    delay(debounce);
    stoppedTime = 0;
    for(uint8_t i=0;i<5;i++){
      bestTimes[i] = 0;
    }
    updateTimes();
    storeTimesEEP();
    timeRunning = 0;
  }

  if(digitalRead(nextPin) == LOW){
    delay(debounce);
    if(rank == 4){
      rank = 0;
    }
    else{
      rank +=1;
    }
    updateTimes();
  }
  
}

void sortTimes(){
    // Nullen im Array temporär durch hohe Zahlen ersetzen: 
    for(uint8_t i = 0; i<5;i++){
      if(bestTimes[i] == 0){
        bestTimes[i] = 4000000; // max. Wert zu stoppen = 3'599'999
      }
    }
    // Bubblesort:
    for(uint8_t n = 4; n>0; n--){
      for(uint8_t i = 0; i<n;i++){
        // Falls linker Wert höher als rechter ODER linker Wert = 0
        if(bestTimes[i]>bestTimes[i+1]){
           // ...beide Werte tauschen:
           tempTime = bestTimes[i];
           bestTimes[i] = bestTimes[i+1];
           bestTimes[i+1] = tempTime;
         }
      }
    }
    // Hohe Zahlen im Array wieder durch Nullen ersetzen: 
    for(uint8_t i = 0; i<5;i++){
      if(bestTimes[i] == 4000000){
        bestTimes[i] = 0; // max. Wert zu stoppen = 3'599'999
      }
    }
}

void updateTimes(){
    lcd.setCursor(8, 0);
    showTime(stoppedTime);
    lcd.setCursor(5,1);
    lcd.print(rank+1);
    lcd.setCursor(8, 1);
    showTime(bestTimes[rank]);
}

void showTime(unsigned long timeMS){
    // Minuten, Sekunden und Hundertstel berechnen:
    minutes = timeMS/60000;
    seconds = (timeMS-minutes*60000)/1000;
    hundreds = (timeMS-minutes*60000-seconds*1000)/10;
    // Werte im gewünschten Format in Array timeString schreiben:
    sprintf(timeString,"%02d:%02d:%02d", minutes, seconds, hundreds);
    // ...und ans LCD ausgeben:
    lcd.print(timeString);
}

void storeTimesEEP(){
    byte byte0; // byte0 = 0...255
    byte byte1; // byte1 = 256...65'535
    byte byte2; // byte2 = 65'536...16'777'215
    for(uint8_t i=0;i<5;i++){
      byte0 = (bestTimes[i] & 0x0000FF);
      byte1 = (bestTimes[i] & 0x00FF00) >> 8;
      byte2 = (bestTimes[i] & 0xFF0000) >> 16;
      EEPROM.write(addresses[i],byte0);
      EEPROM.write(addresses[i]+1,byte1);
      EEPROM.write(addresses[i]+2,byte2);
    }
}

void readTimesEEP(){
     byte byte0; // byte0 = 0...255
     byte byte1; // byte1 = 256...65'535
     byte byte2; // byte2 = 65'536...16'777'215
     for(uint8_t i=0;i<5;i++){
        byte0 = EEPROM.read(addresses[i]);
        byte1 = EEPROM.read(addresses[i]+1);
        byte2 = EEPROM.read(addresses[i]+2);
        bestTimes[i] = byte0 + (byte1 << 8) + (byte2 << 16);
     }
}
</code>
++++
</nodisp>